5.     用proc distance做什么？

我们知道数据变量分四类：名义变量、次序变量、interval变量和ritio变量。但sas里面目前的聚类算法都要求变量时ratio变量。那想要对离散变量进行聚类怎么呢？一种想法自然是讲所有的离散变量都转成0-1变量。这会有如下几个问题：

1)    变量的信息可能会有损失，比如次序型变量转成0-1变量后，次序信息就很难保留；

2)    当离散变量的取值非常多时，转成0-1变量后生成的新变量也会非常多，这样也会造成很多处理上的不便；

3)    0-1变量也没法做标准化等等一些运算，因为这种运算其实是没有意义的

那该如何处理离散变量的聚类呢？答案是用proc distance。我们知道聚类过程中首先是从计算距离或者相似度开始的。一个很自然的想法就是针对离散变量定义有意义的距离（对离散变量和连续变量混合类型的数据）。Proc distance就是用来算这种距离的一个很好的过程。距离或者相似度可以看成是连续数据，自然就可以用sas里面的聚类算法了。

6.     用proc stdize做什么？

前面说过聚类算法首先要算的距离，然后通过距离来执行后续的计算。在距离计算的过程方差比较大的变量影响会更大，这个通常不是我们希望看到。所以非常有必要讲参与聚类的变量转换成方差尽量相同。Proc stdize就能实现这种功能。Proc stdize不仅提供了将变量转换了均值为0，方差转换为1的标准化，还提供了很多其它类型的标准化。比如，range标准化（变量减去最小值除以最大值和最小值得差）

7.     用proc varclus做什么？

在做回归分析的时候，我们知道变量过多会有两个问题：

1)    变量过多会影响预测的准确，尤其当无关紧要的变量引入模型之后；

2)    变量过多不可避免的会引起变量之前的共线性，这个会影响参数估计的精度

聚类分析实际上也存在类似的问题，所以有必要先对变量做降维。说到降维，马上有人会说这个可以用主成分啊，这个的确没错。但是主成分的解释性还是有点差。尤其是第二主成分之后的主成分。那用什么比较好呢？答案是proc varclus——斜交主成分。

我们常说的主成分实际上正交主成分。斜交主成分是在正交主成分的基础上再做了一些旋转。这样得到的主成分不仅能保留主成分的优点（主成分变量相关程度比较低）。另外一方面又能有很到的解释性，并且能达到对变量聚类的效果。使同类别里面的变量尽可能相关程度比较高，不同类别里面的变量相关程度尽可能低。这样根据一定的规则我们就可以在每个类别里面选取一些有代表性的变量，这样既能保证原始的数据信息不致损失太多，也能有效消除共线性。有效提升聚类分析的精度。

8.     用proc mds 和proc princomp做什么？

将原始数据降到两维，通过图形探测整个数据聚类后大致大类别数

9.     用proc aceclus做什么？

聚类算法尤其是k-means算法要求聚类数据是球形数据。如果是细长型的数据或者非凸型数据，这些算法的表现就会相当差。一个很自然的变通想法就是，能不能将非球形数据变换成球形数据呢？答案是可以的。这就要用到proc aceclus。

/*********************************************************/
/*1.模拟数据1;测试标准化方法对聚类的影响
模拟数据，样本量相同，均值和方差不相同*/
/*********************************************************/
data compact;
keep x y c;
n=100;
scale=1; mx=0; my=0; c=1;link generate;
scale=2; mx=8; my=0; c=2;link generate;
scale=3; mx=4; my=8; c=3;link generate;
stop;
generate:
do i=1 to n;
x=rannor(1)*scale+mx;
y=rannor(1)*scale+my;
output;
end;
return;
run;
title ‘模拟数据1’;
proc gplot data=compact;
plot y*x=c;
symbol1 c=blue;
symbol2 c=black;
symbol3 c=red;
run;

proc stdize data=compact method=std
out=scompacted2;
var x y;
run;
title ‘标准化后的模拟数据1’;
proc gplot data=scompacted2;
plot y*x=c;
symbol1 c=blue;
symbol2 c=black;
symbol3 c=red;
run;

/*********************************************************/
/*2.create result table*/
/*********************************************************/
data result;
length method$ 12;
length misclassified 8;
length chisq 8;
stop;
run;

%let inputs=x y;
%let group=c;
%macro standardize(dsn=,nc=,method=);
title “&method”;
%if %bquote(%upcase(&method))=NONE %then %do;
data temp;
set &dsn;
run;
%end;
%else %do;
proc stdize data=&dsn method=&method out=temp;
var &inputs;
run;
%end;
proc fastclus data=temp maxclusters=&nc least=2
out=clusout noprint;
var &inputs;
run;
proc freq data=clusout;
tables &group*cluster / norow nocol nopercent
chisq out=freqout;
output out=stats chisq;
run;
data temp sum;
set freqout end=eof;
by &group;
retain members mode c;
if first.&group then do;
members=0; mode=0;
end;
members=members+count;
if cluster NE . then do;
if count > mode then do;
mode=count;
c=cluster;
end;
end;
if last.&group then do;
cum+(members-mode);
output temp;
end;
if eof then output sum;
run;
proc print data=temp noobs;
var &group c members mode cum;
run;
data result;
merge sum (keep=cum) stats;
if 0 then modify result;
method = “&method”;
misclassified = cum;
chisq = _pchi_;
pchisq = p_pchi;
output result;
run;
%mend standardize;

%standardize(dsn=compact,nc=3,method=ABW(.5));
%standardize(dsn=compact,nc=3,method=AGK(.9));
%standardize(dsn=compact,nc=3,method=AHUBER(.5));
%standardize(dsn=compact,nc=3,method=AWAVE(.25));
%standardize(dsn=compact,nc=3,method=EUCLEN);
%standardize(dsn=compact,nc=3,method=IQR);
%standardize(dsn=compact,nc=3,method=L(1));
%standardize(dsn=compact,nc=3,method=L(2));
%standardize(dsn=compact,nc=3,method=MAD);
%standardize(dsn=compact,nc=3,method=MAXABS);
%standardize(dsn=compact,nc=3,method=MEAN);
%standardize(dsn=compact,nc=3,method=MEDIAN);
%standardize(dsn=compact,nc=3,method=MIDRANGE);
%standardize(dsn=compact,nc=3,method=NONE);
%standardize(dsn=compact,nc=3,method=RANGE);
%standardize(dsn=compact,nc=3,method=SPACING(.3));
%standardize(dsn=compact,nc=3,method=STD);
%standardize(dsn=compact,nc=3,method=SUM);
%standardize(dsn=compact,nc=3,method=USTD);

proc sort data=result;
by misclassified;
run;
title ‘汇总数据’;
title2 ‘聚类判定类别错误样本数排序’;
proc print data=result;
run;