sas信用评分之手动对数值变量分组

上周内容已经有了预告，就是除了我之前发表的最优分段，我自认为比较实际的分段方法这个方法我是借鉴了别人的经验已经根据自己的业务经验做的手工分组，相对于之前的最优分组来说，就是因为是主观去手动去分组，所以可能分的组别可能更贴近业务，对于模型后续的稳定性或者跨期验证效果会好一些，但是我这不是打脸，就是最优分段就是没用的哈。最优分段在什么下可以使用呢，譬如户籍地这种情况很多的变量，你对于分组没有丝毫的头绪，那么可以就扔进最优分组去自动分组。但是这里切记一点，当数据较少的时候，什么叫数据较少，就是少于20000的时候。切记设置最少的一组至少都要100个人，不然就过拟合啦。这样子的分组，会让模型不稳定。
    那么进入正题。之前已经贴过等量分组的代码。也有人在留言区说proc rank的过程也可以分组。等量等宽分组的方法很多，我也是按照我的经验去写。但是因为我之前每周都会贴代码，要是这周没贴，会不会有些人，你这么说，又没给代码我还得自己写代码，那这篇文章岂不是白写了吗。好吧，介于我这篇文章能有用，我还是贴代码。贴的是数值的等距分组，因为上周的那篇文章的代码（顿时有种自己在写R包的感觉。不要骂我臭不要脸）：
options compress=yes;

%macro data_split(schema,table_name,N,Y,column);

proc sql;

create table &schema..&table_name._rank(

table_name   varchar(100)

,col_name  varchar(50)

,rank_name numeric

,low                           numeric

,up numeric

,cnt  numeric

,rate   numeric

,n1   numeric

,bad_rate    numeric

,woe   numeric

,iv  numeric

,split_type  numeric

);

quit;

proc sql;/*获得总记录数、总坏客户数、总好客户数*/

select count(*),SUM(&Y),count(*)-SUM(&Y) into :record_cnt,

:bad_cnt,

:good_cnt

from   &schema..&table_name;

quit;


/*2-----不指定分箱的变量,取所有连续变量*/


%if &column = %str() %then

%do;

proc contents /*获取输入数据集的所有变量信息*/

data=&schema..&table_name

out=work.&table_name._CONT

noprint;

run;


data work.&table_name._CONT;

set work.&table_name._CONT;

where  NAME<>"&Y." AND NAME<>"APPL_ID";

run;/*不包含Y值*/


data _null_;/*获取输入数据集中的变量个数，并定义宏变量*/

call symput('NUMOBS',put(NUMOBS, 12.));

stop;

set work.&table_name._CONT nobs=NUMOBS ;

run;

%do I=1 %TO &NUMOBS.;/*循环获取变量表里面的变量*/

%put &NUMOBS.||&I.;

data _null_;

pointer=&I.;

set work.&table_name._CONT POINT=POINTER;

call symput('col_name', NAME);

call symput('TYPE', put(TYPE, 1.));

stop;

run;

/*仅对数值变量进行逐个处理*/

%if &TYPE.=1 %then %do;

proc rank data= &schema..&table_name(keep = &col_name &Y) out = data_rank ties = low groups = &N;

var &col_name;

ranks new_rank;

run;


proc sql;

insert into &schema..&table_name._rank(

table_name

,col_name

,rank_name

,low

,up

,cnt

,rate

,n1

,bad_rate

,woe

,iv

,split_type)

select "&table_name"

,"&col_name"

,new_rank

,min(&col_name)

,max(&col_name)

,count(1)

,count(1)/&record_cnt

,sum(&Y)

,sum(&Y)/count(1)

,log((ifn(sum(&Y)=0,0.001,sum(&Y))/&bad_cnt)/((count(1)-sum(&Y))/&good_cnt))

,(sum(&Y)/&bad_cnt-(count(1)-sum(&Y))/&good_cnt)*log((ifn(sum(&Y)=0,0.001,sum(&Y))/&bad_cnt)/((count(1)-sum(&Y))/&good_cnt))

,&N

from   data_rank

group by new_rank;

quit;/*将分组的结果插入rank表，并计算每个变量每个分组的坏客户数、坏客户占比、WOE、IV*/

%end;

%end;

%end;

%else

%do;

proc rank data= &schema..&table_name(keep = &column &Y) out = data_rank ties=mean groups = &N;

var &column;

ranks new_rank;

run;

proc sql ;

insert into &schema..&table_name._rank(

table_name

,col_name

,rank_name

,low

,up

,cnt

,rate

,n1

,bad_rate

,woe

,iv

,split_type

)

select "&schema..&table_name"

,"&column"

,new_rank

,min(&column)

,max(&column)

,count(1)

,count(1)/&record_cnt

,sum(&Y)

,sum(&Y)/count(1)

,log((ifn(sum(&Y)=0,0.001,sum(&Y))/&bad_cnt)/((count(1)-sum(&Y)))/&good_cnt))

,(sum(&Y)/&bad_cnt-(count(1)-sum(&Y))/&good_cnt)*log((ifn(sum(&Y)=0,0.001,sum(&Y))/&bad_cnt)/((count(1)-sum(&Y)))/&good_cnt))

,&N

from  data_rank

group by new_rank;

quit;

%end;

/*4.将具体分组表转化成用于生成excel数据源的格式*/

data &schema..&table_name._rank;

set &schema..&table_name._rank;

if low=" " then low=-1000;

ARRAY var

rank_name

up

;

DO OVER var ;

IF var="" THEN var=-999;

END;

run;


proc sort data=&schema..&table_name._rank;

by col_name;

run;


data &schema..&table_name._rank;

set &schema..&table_name._rank;

by col_name;

clus+1;

if first.col_name then clus=1;

run;


data &schema..&table_name._rank;

set &schema..&table_name._rank;

by col_name;

retain t;

if _n_>1 then low=t;

t=up;

run;


data &schema..&table_name._rank;

set &schema..&table_name._rank;

if clus=1 and rank_name=-999 then low=-1000;

if clus=1 and rank_name=0 then low=-0.1;

if clus=2 and low=-999 then low=-0.1;

run;


proc sql noprint;

create table &schema..&table_name._rank as

(

select t1.table_name,t1.col_name,t1.rank_name,t1.low,case when t2.clus is not null then 10e8 else t1.up end as up

,t1.cnt,t1.rate,t1.n1,t1.bad_rate,t1.woe,t1.iv,t1.split_type,t1.clus

from &schema..&table_name._rank as t1

left join

(

select col_name,max(clus) as clus from &schema..&table_name._rank

group by col_name )as t2

on t1.col_name=t2.col_name

and t1.clus=t2.clus

);

run;/*将最大分组的上限设置成10e8*/


data &schema..&table_name._rank;

set &schema..&table_name._rank;

testname=compress("("||low||","||up||"]",'');

run;/*将上下限进行合并，生成各分组的取值范围并去掉了中间的空格*/


/*取类似于excel变量分组的数据源*/

proc sql noprint;

create table &schema..&table_name._rank_excel as

(

select * from

(select t1.col_name as col_name1,t1.col_name as col_name2,'' as testname,'' as clus,'' as n,'' as n1

from &schema..&table_name._rank as t1

where clus=1)

union all

(select t2.col_name as col_name2,'' as col_name2,t2.testname,t2.clus,t2.cnt as n,t2.n1

from &schema..&table_name._rank as t2)

)

;

quit;

proc sql noprint;

create table &schema..&table_name._iv as

(select col_name,sum(iv) as iv from &schema..&table_name._rank

group by col_name)

;

quit;

proc sort data=&schema..&table_name._iv;

by descending iv ;

quit;

%mend data_split;

关于这段代码中用到的proc rank可以看之前的这篇文章：proc rank过程。

还是老样子，讲解一下怎么代码怎么用。

data_split(schema,table_name,N,Y,column);

schema：填入你的数据集的逻辑库。

table_name：填入你的数据集，不带逻辑库名。

N:你要分几组。

Y：因变量。

Column：这个参数就让他空就可以了。我是写多了，但是又忘记改回来。

就是你填入这几项就可以了按以下这个顺序：

%data_split(逻辑库,表名,分箱数,因变量);

到这里我都是在讲代码，现在来讲手动分组的内容。首先代码跑出来有几张表，最重要就是这样表“你的表名__rank”的这种表是重点。

这是我分10组粗分类的情况。我会将这张表导出成excel.
然后以这个变量为例哈。
这里注意一件事。就是low=-1000 up=-999代表就是空值，在最优分组中。空值将成为单独的一组，但是我们手动分组中就不这么做了，我们会将空值放在跟一组与其woe相近的组别在一起。除非真的空值的woe值真的特别突出，那么就单独成为一组，这种情况你就自己判断哈，随机应变哈，发挥你的脑回路的时候到了。
  回到excel的内容：

这部分很繁琐的原因是，譬如我现在有100多个变量是iv值是可以达到我的要求的话，那么就是我要手动分100多个变量的，说实话我觉得这样子我挺白痴，但是我又觉得是有用的变量，分组的问题本来就重要，那就白痴我也要亲自分段。无非就多花几个小时在搞这个事情。导出excel后，为了让变量的分成可以清晰一些，我会利用色阶让我好判断一些。

其实这个变量是比较好分层的。按照色阶的颜色，我们就把细分类给分出来了。这里为什么对bad_rate和woe都标了色阶，是因为当我在判断分组时候会以woe为主，bad_rate为辅去分组。

其实对于我个人建模，分为五组，我还是觉得有点多了。但是介于这个变量woe分层情况，所以这样子看也可以接受。我刚才说了对于null的组别，是可以跟别的组在一起的，但是这里他特立独行的一个颜色，我也没办法把他跟别的组放一起。讲到空值还有一个问题，就是在连续变量等量分组时候，空值会被变成独立的一组，那么这时候，假设如果你的变量null不是很多，而且你可以用你别的组别填充的话，建议填充。因为假设你的数据大概有20000，但是null可能就30个，这种占比其实是很小，你为这30个特地设了一个分组，你要是觉得可以那也就可以吧，具体听你的领导的哈。

回到分组的问题，你分好组之后再回去更新到主表中去算woe。这部分代码我就不贴了，要是你觉得你没有思路，实在写不出来，你可以找我要。还是那句话。自己工作自己的作业自己做，你写了整个代码的架构，你报错我可以帮你改，但是你什么都没写，直接说你不会写，我是不会帮你，请粉丝们理解